/* La courbe orthoptique d'une courbe est le lieu des points
   d'où l'on "voit" la courbe sous un angle droit.
   L'orthoptique d'une conique à centre d'excentricité inférieure à rac(2)
   est un cercle appelé cercle orthoptique ou cercle de Monge.
   Pour l'ellipse d'équation x^2/a^2+y^2/b^2=1,
   le cercle de Monge a pour équation :  x^2+y^2 = a^2+b^2
*/   
import geometry;
import animate;
settings.tex="pdflatex";
settings.outformat="pdf";

size(7.5cm,0);

animation Anim;
real a=3, b=2, r=sqrt(a^2+b^2);
pair pM;
path cerclemonge;

show(currentcoordsys);

ellipse Ell = ellipse((0,0), a, b);
draw(Ell,red);

draw(Label("$D_1$",align=E),Ell.D1,.8bp+lightgray);
draw(Label("$D_2$",align=W),Ell.D2,.8bp+lightgray);
dot("$F_1$",Ell.F1,N,3bp+gray);
dot("$F_2$",Ell.F2,N,3bp+gray);

for(int k=0; k<360; k+=4) {
  pM=rotate(k,(0,0))*(r,0);
  cerclemonge=cerclemonge..pM;
  save();
  draw(cerclemonge,1bp+black);
  line[] tgs=tangents(Ell, pM);
  draw(tgs,0.8*blue);
  perpendicularmark(tgs[0],tgs[1]);
  addMargins(1cm,1cm);
  label("\scriptsize Le cercle de Monge d'\'equation $x^2+y^2=a^2+b^2$ ...",
        (0,1.5*r),Fill(paleblue));
  label("\scriptsize ... de l'ellipse d'\'equation $\frac{x^2}{a^2}+\frac{y^2}{b^2}=1$",
        (0,-1.5*r),Fill(white));
  Anim.add();
  restore();
}
Anim.movie(); // remplacer par la ligne suivante
// label(A.pdf(BBox(1mm,nullpen),delay=500,"controls,loop"));
// pour obtenir une animation dans une seule page d'un pdf.
// controls : pour obtenir les boutons,
// loop : pour que cela tourne en boucle par défaut.