// Définition du type JOUEUR : chaque instance de ce type 
// est caractérisée par - un nom,
//                      - un salaire.
struct joueur {
  string nom;
  real   salaire;
  void operator init(string nom, real salaire){
    this.nom=nom;
    this.salaire=salaire;
  }
}
// Définition du type EQUIPE : chaque instance de ce type 
// est caractérisée par - un nom d'équipe, 
//                      - une liste de joueurs (liste d'éléments de type JOUEUR)
//                      - le montant total des salaires des joueurs de l'équipe
//                        qui est calculé via la fonction totaldessalaires().
struct equipe {
  string   nom_equipe;
  joueur[] joueursdelequipe;
  real     totaldessalaires;  
  void operator init(string nom_equipe,joueur[] joueursdelequipe=new joueur[]){
    this.nom_equipe=nom_equipe;
    this.joueursdelequipe=joueursdelequipe;
    this.totaldessalaires=0;
  }
  void totaldessalaires(){
    for(int i=0; i<joueursdelequipe.length; ++i)
     this.totaldessalaires+=joueursdelequipe[i].salaire;
  }
}
// Un exemple d'objet de type EQUIPE : eq1
equipe eq1=equipe("France",
                  new joueur[] {joueur("Dupont",150000),
                                joueur("Durand",200000),
                                joueur("Martin",250000)});

// Affichage de quelques valeurs particulières
size(6cm);
label(eq1.joueursdelequipe[1].nom,(0,0)); // le nom du 2ème joueur de eq1
label(string(eq1.joueursdelequipe[2].salaire),(1,-1)); // le salaire du 3ème joueur
label(string(eq1.joueursdelequipe.length),(2,-2)); // le nombre de joueurs de eq1

label(string(eq1.totaldessalaires),(3,-3)); // le total des salaires avant calcul
eq1.totaldessalaires();
label(string(eq1.totaldessalaires),(3,-4)); // le total des salaires après calcul