import graph3;
import palette;

size(8cm);
currentprojection=perspective(camera=(5,4,-5),up=Y);
currentlight=nolight;

pen[] couleur={orange,red};

real c=1; // demi-distance focale
int  n=4; // nombre d'hyperboloïdes
real vx=1.5,
     vy=vx; 

for(int i=0; i<n; ++i){
  real d=(i+1)*c/(n+1);
  real a=sqrt(c^2-d^2);
  real f(pair z) {return d*sqrt(abs(z)^2/a^2+1);}
  surface s=surface(f,(0,-vy),(vx,vy),4,4,Spline);
  draw(s,couleur[i%couleur.length]);
  draw(rotate(180,X)*s,couleur[i%couleur.length]);

  real x(real t) {return vx;}
  real y(real t) {return t;}
  real z(real t) {return d*sqrt(1+(t^2+vx^2)/a^2);}
  path3 p=graph(x,y,z,-vy,vy,operator ..);
  draw(p^^rotate(180,X)*p,blue);
}
path3 pl0=(vx,vy,0)--(vx,-vy,0)--(0,-vy,0)--(0,vy,0)--cycle;
draw(surface(pl0),red);
draw((vx,-vy,0)--(vx,vy,0),blue);

dot((0,0,c),red);
dot((0,0,-c),red);

path3 pl=(0,vy,1.8vx)--(0,vy,-1.8vx)
          --(0,-vy,-1.8vx)--(0,-vy,1.8vx)--cycle;
surface plan=surface(pl);		  
draw(plan,grey);
draw(shift(vx,0,0)*plan,lightgrey+opacity(.8),.8blue);

limits((-.5vx,-1.5vy,-vx),(1.5vx,1.3vy,vx));
xaxis3("$x$",Arrow3);
yaxis3("$y$",Arrow3);