// VERSION PROVISOIRE
// 1. Des améliorations sont prévues pour la saisie des nombres.
// 2. Je n'oublie pas les traits qui manquent.

import math;
import fontsize;
usepackage("fourier");
defaultpen(fontsize(20pt));

size(10cm,0);

void jalousie(int[] a, int[] b) {
    int[][][] produit=new int[a.length][b.length][2];
    real decal=0.25;
    int[] totaldiag; for(int z=0; z<a.length+b.length; ++z) totaldiag.push(0);
    int   d=0, x, y;
    for(int j=0; j<a.length+b.length-1; ++j)
    { 
        if(j<b.length) { x=0; y=j;
                         label(string(b[y]),(1,y+1-b.length)); }
                         //draw((.5,y+1.5-b.length)--(-.5-y-2decal,.5-b.length-2decal)); }
        else { x=j-b.length+1; y=b.length-1;
               label(string(a[j+1-b.length]),(-(j+1-b.length),1)); 
        }
        while(x<a.length && y>=0) {
            produit[x][y][0]=(a[x]*b[y])%10;
            produit[x][y][1]=(int) ((a[x]*b[y]-produit[x][y][0])/10);
            totaldiag[d]+=produit[x][y][0];
            totaldiag[d+1]+=produit[x][y][1];
            label(string(produit[x][y][0]),(-x+decal,y+1-b.length-decal),Pen(d));
            label(string(produit[x][y][1]),(-x-decal,y+1-b.length+decal),Pen(d+1));
            ++x;--y;
        }
    ++d;
    }
    label(string(a[0]),(0,1));
    d=0;
    int x=0, y=-b.length, retenue;
    for(int c=0; c<a.length+b.length; ++c) {
        label(string(totaldiag[c]%10),(x-decal,y+decal),Pen(d));
        if(c< a.length+b.length-1){
            retenue=(int) ((totaldiag[c]-totaldiag[c]%10)/10);
            totaldiag[c+1]+=retenue;
            if(retenue!=0){
               real xdelta=(c<b.length-1)?.4:b.length-c-1;
               real ydelta=(c<b.length-1)?-b.length+c+2:.4;
               label(scale(.5)*format("(%i)",retenue),(xdelta,ydelta),Pen(d));
            }
        }
        if(c<a.length-1) {--x;}
        else {x=-a.length; ++y; decal=-.25;}
        ++d;
    }
    add(shift(-a.length+.5,-b.length+.5)*grid(a.length,b.length));
}

int[] a={5,3,7,4},
      b={6,2,9,1,2,7,7};

jalousie(a,b);

// Pour mettre en évidence quelques cases :
real a=.45;
path cadre1=(-a,-a)--(a,-a)--(a,a)--(-a,a)--cycle,
     cadre2=scale(1.2a)*unitcircle,
     cadre3=scale(1.2a)*polygon(8);
draw(shift(0,0)*cadre1,3bp+red);
draw(shift(-1,-4)*cadre2,3bp+green);
draw(shift(-3,-1)*cadre3,3bp+purple);

shipout(bbox(2mm,white));